©2025 CJDinfo®

Detalhe Solução

ASP: Alinhamento e tratamento de Strings:

'-------------------------------------------------------------------
' StrNull
' Retorna a String do Dado, filtrando o Nulo
'-------------------------------------------------------------------
Function StrNull(Dado)

If IsNull(Dado) Then
        StrNull = ""
    Else
        StrNull = CStr(Dado)
    End If
End Function

'-------------------------------------------------------------------
' StrC
' Acerta a String na Largura dada com Alinhamento ao Centro
'-------------------------------------------------------------------
Function StrC(Dado, Larg)

Dim Comp, s, s1

' Se Dado Nulo, converte para "":
    s = StrNull(Dado)

Comp = Len(s)
    If Comp >= Larg Then                            'Se Maior que a largura:
        StrC = Right(s, Larg)                       'Trunca-a
    Else
        s1 = Space((Larg - Comp) / 2) & s           'Senão, completa-a com
        StrC = s1 & Space(Larg - Len(s1))           'Espaços ao redor.
    End If
End Function

'-------------------------------------------------------------------
' StrD
' Acerta a String na Largura dada com Alinhamento à Direita
'-------------------------------------------------------------------
Function StrD(Dado, Larg)

Dim Comp, s

' Se Dado Nulo, converte para "":
    s = StrNull(Dado)

Comp = Len(s)
    If Comp >= Larg Then                    'Se Maior que a largura:
        StrD = Right(s, Larg)               'Trunca-a
    Else
        StrD = Space(Larg - Comp) & s       'Senão, completa-a com Espaços.
    End If
End Function

'-------------------------------------------------------------------
' StrE
' Acerta a String na Largura dada com Alinhamento à Esquerda
'-------------------------------------------------------------------
Function StrE(Dado, Larg)

Dim Comp, s

' Se Dado Nulo, converte para "":
    s = StrNull(Dado)

Comp = Len(s)
    If Comp >= Larg Then                    'Se Maior que a largura:
        StrE = Left(s, Larg)                'Trunca-a
    Else
        StrE = s & Space(Larg - Comp)       'Senão, completa-a com Espaços.
    End If
End Function

'-------------------------------------------------------------------
' StrNum
' Retorna o valor Numérico em String Dado, formatado na Largura
' dada, tratando-o com relação à Nulos
'-------------------------------------------------------------------
Function StrNum(Dado, Larg)

Dim s

' Trata com relação à Nulos:
    s = StrNull(Dado)

' Completa com Zeros à esquerda ou Trunca:
    If Len(s) < Larg Then
        s = String(Larg - Len(s), "0") + s
    Else
        s = Right(s, Larg)
    End If
    StrNum = s
End Function

¤ Links Relacionados:
- Veja todas as soluções do site

Gostou? Compartilhe ou comente:

Retornar